Amiga Format CD 44/Amiga Format CD44 (1999-08-26)(Future Publishing)(GB)(Track 1 of 3)[!][issue 1999-10].iso/-in_the_mag-/basics/amos/artcoder.lha/ArtCoder/ArtCoder.AMOS/ArtCoder.amosSourceCode

AMOS Source Code | 1993-10-29 | 35KB | 1,043 lines

' Amos Art Coder -- Writes code to re-create your drawing.
' Copyright 1993, Steve Tiffany.  All rights reserved.
Dim OLDPAL$(32) : SCRNCHECK : If GOTTASETUP Then SCRNSETUP : SCRNCENTER
'If Text buffer is less than 20000, increase it (in AMOS 1.3) with  Alt - F9.
'                         or (in AMOS Pro) with Left Amiga - Shift - T
'Merge code (Ram:ArtCode.asc) here, using (in AMOS 1.3)  Shift - F5:
'                         or (in AMOS Pro)  Left Amiga - Shift - M









'***************************************************
For J=0 To 31 : OLDPAL$(J)=Hex$(Colour(J)) : Next J
Change Mouse 4 : MMODE=4
Unpack 7 To 1 : Wind Save
If Ntsc=0
   Screen Display 1,112,265,320,25
End If
Screen 1 : Get Palette 0
HIDFLAG=0 : OUTFLAG=0 : BX=159 : ARTMODE=0 :
'CODEWIDTH=200
CODEWIDTH=60
Screen 1 : Ink 0,,0 : If NUMCOLORS<32 Then Bar 159,12 To 319,24
If NUMCOLORS<16 Then Bar 239,0 To 319,12
If NUMCOLORS<8 Then Bar 199,0 To 239,12
If NUMCOLORS<4 Then Bar 179,0 To 199,12
Reserve Zone 6
Screen 0 : Gr Writing 1 : GRMODE=1
Proc CHECKPATTERN : HOLDCOLOR=CURRCOLOR
If CURRCOLOR<16
   ICONROWNUM=0 : ICONCOLNUM=CURRCOLOR
Else
   ICONROWNUM=1 : ICONCOLNUM=CURRCOLOR-16
End If
BX=(ICONCOLNUM*10)+159 : BY=(ICONROWNUM*12)
Screen 1 : Ink 17 : Box BX,BY To BX+10,BY+12

Open Out 1,"ram:ArtCode.asc"
Open Out 2,"ram:XYclip.asc"
Wait Vbl
If Ntsc
   Limit Mouse 112,215 To 431,239 : Rem : until they  an pick artmode
Else
   Limit Mouse 112,265 To 431,289
End If

Do
   K$=Inkey$ : SCODE=Scancode
   If SCODE=89 : Rem : user selected F10 to toggle tool bar...
      If HIDFLAG=0
         Screen Hide 1 : HIDFLAG=1
      Else
         Screen Show 1 : HIDFLAG=0
      End If
   End If
   If SCODE=64 Then CLICKHANDLER["POLYEND"]
   If K$="D" Then CLICKHANDLER["PGON"]
   If K$="d" Then CLICKHANDLER["PLINE"]
   If K$="v" Then CLICKHANDLER["SEG"]
   If K$="r" Then CLICKHANDLER["RECBOX"]
   If K$="R" Then CLICKHANDLER["RECBAR"]
   If K$="f" Then CLICKHANDLER["PNT"]
   If K$="p" Then CLICKHANDLER["PAL"]
   If K$="t" Then CLICKHANDLER["TXT"]
   If K$="Q" Then CLICKHANDLER["QUIT"]
   If K$="," Then CLICKHANDLER["COMMA"]
   If ARTMODE=4 or ARTMODE=5
      Screen 0
      Gr Writing 3
      HOLDXM=X Screen(X Mouse) : HOLDYM=Y Screen(Y Mouse)
      Draw HOLDXM,0 To HOLDXM,SCRNHEIGHT-1
      Draw 0,HOLDYM To SCRNWIDTH-1,HOLDYM
      Draw HOLDXM,0 To HOLDXM,SCRNHEIGHT-1
      Draw 0,HOLDYM To SCRNWIDTH-1,HOLDYM
      Gr Writing 1
   End If
   If Mouse Click=1 Then CLICKHANDLER[""]
Loop

Procedure CLICKHANDLER[ROUTINE$]
   Shared OUTFLAG,BX,BY,ARTMODE,CURRCOLOR,LCOUNT,NEWFLAG,HOLDXM,HOLDYM,CODEWIDTH
   Shared NUMDOTS,WORD$,CURRRED,CURRGREEN,CURRBLUE,CHEXR$,CHEXG$,CHEXB$,OLDPAL$()
   Shared XOFFSET,YOFFSET,XLIMIT,YLIMIT,NUMCOLORS,PATNUM,PCOLOR,GRMODE,CFLAG
   Shared HOLDCOLOR,HIDFLAG,MMODE,SCRNHEIGHT,SCRNWIDTH
   XM=X Mouse : YM=Y Mouse

   CURRSCREEN=Scin(XM,YM)
   If ROUTINE$<>"" Then CURRSCREEN=1
   Screen CURRSCREEN
   XM=X Screen(XM) : YM=Y Screen(YM)

'if it's a color or a new artmode on Screen 1...
   If CURRSCREEN=1
'     first take care of all the X,Y's that have accumulated, if any...
      If Lof(2)>0
         If ARTMODE=1
            Gosub ARTMODE1
         End If
         If ARTMODE=2
            Gosub PLUSINK
            Close 2 : Open In 2,"ram:XYclip.asc" : Gosub CHECKWIDTH
            Print #1,"Polyline "; : Add LCOUNT,9
            Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
            Print #1,X;",";Y; : Gosub LLENNY
            While Not Eof(2)
               Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
               X$=X$-" " : Y$=Y$-" "
               Print #1," To ";X$;",";Y$; : Add LCOUNT,4
               Gosub LLENNY
               If LCOUNT>CODEWIDTH and Pof(2)<Lof(2)
                  Print #1,"" : Print #1,"Polyline "; : LCOUNT=9
               End If
            Wend
            NEWFLAG=1 : Print #1," : "; : Add LCOUNT,3
            Close 2 : Open Out 2,"ram:XYclip.asc"
         End If
         If ARTMODE>2 and ARTMODE<6
            Gosub PLUSINK : Close 2 : Open In 2,"ram:XYclip.asc"
            If ARTMODE=3
               BXBAR$="Draw "
            End If
            If ARTMODE=4
               BXBAR$="Box "
            End If
            If ARTMODE=5
               Gosub CHECKWIDTH
               If GRMODE<>1
                  Print #1,"Gr Writing 1 : "; : GRMODE=1 : Add LCOUNT,15
               End If
               BXBAR$="Bar "
            End If
            While Not Eof(2)
               Gosub CHECKWIDTH
               Input #2,X$ : Input #2,Y$ : Input #2,X2$ : Input #2,Y2$
               X=Val(X$) : Y=Val(Y$) : X2=Val(X2$) : Y2=Val(Y2$)
               Print #1,BXBAR$; : Add LCOUNT,5
               X$=X$-" " : Y$=Y$-" " : X2$=X2$-" " : Y2$=Y2$-" "
               Print #1,X$;",";Y$; : Gosub LLENNY : Add LCOUNT,1
               Print #1," To ";X2$;",";Y2$; : Add LCOUNT,5
               X=Val(X2$) : Y=Val(Y2$) : Gosub LLENNY : Rem so lenny's accurate
               Print #1," : "; : Add LCOUNT,3 : Gosub CHECKWIDTH
            Wend
            NEWFLAG=1
            Close 2 : Open Out 2,"ram:XYclip.asc"

         End If
         If ARTMODE=6
            Gosub PLUSINK : Close 2 : Open In 2,"ram:XYclip.asc"
            Gosub CHECKWIDTH
            While Not Eof(2)
               Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$) : Gosub LLENNY
               Print #1,"Paint ";X$;",";Y$;" : "; : Add LCOUNT,10
               Gosub CHECKWIDTH
            Wend
            NEWFLAG=1
            Close 2 : Open Out 2,"ram:XYclip.asc"

         End If
         If ARTMODE=7
            Gosub PLUSINK : Close 2 : Open In 2,"ram:XYclip.asc"
            Gosub CHECKWIDTH
            If GRMODE<>0
               Print #1,"Gr Writing 0 : "; : GRMODE=0 : Add LCOUNT,15 : Gosub CHECKWIDTH
            End If
            WORDLENGTH=Len(WORD$)
            If(WORDLENGTH+LCOUNT+15)>CODEWIDTH
               Print #1,"" : LCOUNT=0
            End If
            While Not Eof(2)
               Gosub CHECKWIDTH
               Print #1,"Text "; : Add LCOUNT,5
               Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
               X$=X$-" " : Y$=Y$-" "
               Print #1,X$;",";Y$;","; : Gosub LLENNY : Add LCOUNT,7
               Print #1,Chr$(34);WORD$;Chr$(34);" : "; : Add LCOUNT,WORDLENGTH
               Gosub CHECKWIDTH
            Wend
            NEWFLAG=1 :
            Close 2 : Open Out 2,"ram:XYclip.asc"

         End If
         If ARTMODE=8
            Gosub PLUSINK : Close 2 : Open In 2,"ram:XYclip.asc"
            While Not Eof(2)
               Gosub CHECKWIDTH
               Print #1,"Ellipse "; : Add LCOUNT,8
               Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
               X$=X$-" " : Y$=Y$-" "
               Print #1,X$;",";Y$; : Gosub LLENNY : Add LCOUNT,1
               Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
               X$=X$-" " : Y$=Y$-" "
               Print #1,",";X$;",";Y$; : Gosub LLENNY : Add LCOUNT,2
               Print #1," : "; : Add LCOUNT,3 : Gosub CHECKWIDTH
            Wend
            NEWFLAG=1
            Close 2 : Open Out 2,"ram:XYclip.asc"
         End If
      End If

' they've used a keyboard equivalent...
   If ROUTINE$<>""
      Limit Mouse XOFFSET,YOFFSET To XLIMIT,YLIMIT
      Gosub ROUTINE$ : Pop Proc
   End If

' they're picking a color from the grid...
      If XM>158
         Gosub CLEARCOLORGRID
         ICONCOLNUM=((XM-160)/10)
         If ICONCOLNUM>NUMCOLORS-1
            ICONCOLNUM=NUMCOLORS-1
         End If

         ICONROWNUM=(YM)/13
         If NUMCOLORS<32
            ICONROWNUM=0
         End If

         CURRCOLOR=ICONCOLNUM+(ICONROWNUM*16)

         BX=(ICONCOLNUM*10)+159 : BY=(ICONROWNUM*12)
         Ink 17 : Box BX,BY To BX+10,BY+12
         Screen 0 : Ink CURRCOLOR : CFLAG=1

      Else
'     they're picking a new artmode...
         ICONCOLNUM=((XM)/40)+1
         ICONROWNUM=(YM)/13
         ICONID=ICONCOLNUM+(ICONROWNUM*4)
         On ICONID Gosub PGON,PLINE,SEGPAINT,BBOXBAR,OUTLYN,PATTERN,TXTPAL,CIRCQUIT
      End If
      If ARTMODE>0
         Limit Mouse XOFFSET,YOFFSET To XLIMIT,YLIMIT
      End If
      Pop Proc
   End If

'from here on it's an X,Y coordinate on Screen 0...
   If ARTMODE=1
      If NEWFLAG=1
         Print #2,XM : Print #2,YM
         NEWFLAG=0 : HOLDXM=XM : HOLDYM=YM : NUMDOTS=1 : NUMDOT$=Str$(NUMDOTS)-" "
         Ink 1,0 : Gr Writing 1 : Text 5,16,NUMDOT$ : Ink CURRCOLOR,PCOLOR
      End If
      Screen 0
      While Mouse Key=1
         XM2=X Screen(X Mouse) : YM2=Y Screen(Y Mouse) : Gr Writing 3
         Draw HOLDXM,HOLDYM To XM2,YM2
         Draw HOLDXM,HOLDYM To XM2,YM2
      Wend
      Gr Writing 1 : Draw HOLDXM,HOLDYM To XM2,YM2
      HOLDXM=XM2 : HOLDYM=YM2
      Print #2,HOLDXM : Print #2,HOLDYM
      Ink 1,0 : Inc NUMDOTS : NUMDOT$=Str$(NUMDOTS)-" " : Text 5,16,NUMDOT$
      Ink CURRCOLOR,PCOLOR
      If NUMDOTS=15
         Gosub ARTMODE1
      End If

   End If
   If ARTMODE=2
      If NEWFLAG=1
         Print #2,XM : Print #2,YM
         NEWFLAG=0 : HOLDXM=XM : HOLDYM=YM
      End If
      Screen 0
      While Mouse Key=1
         XM2=X Screen(X Mouse) : YM2=Y Screen(Y Mouse)
         Gr Writing 3 : Draw HOLDXM,HOLDYM To XM2,YM2
         Draw HOLDXM,HOLDYM To XM2,YM2
      Wend
      Gr Writing 1 : Draw HOLDXM,HOLDYM To XM2,YM2
      HOLDXM=XM2 : HOLDYM=YM2
      Print #2,HOLDXM : Print #2,HOLDYM
   End If

   If ARTMODE=3
      NEWFLAG=0 : HOLDXM=XM : HOLDYM=YM
      Screen 0
      While Mouse Key=1
         XM2=X Screen(X Mouse) : YM2=Y Screen(Y Mouse)
         Gr Writing 3 : Draw HOLDXM,HOLDYM To XM2,YM2
         Draw HOLDXM,HOLDYM To XM2,YM2
      Wend
      Gr Writing 1 : Draw HOLDXM,HOLDYM To XM2,YM2
      Print #2,HOLDXM : Print #2,HOLDYM
      Print #2,XM2 : Print #2,YM2
   End If

   If ARTMODE=4 or ARTMODE=5
      NEWFLAG=0 : HOLDXM=XM : HOLDYM=YM
      Screen 0 : Gr Writing 3
      While Mouse Key=1
         XM2=X Screen(X Mouse) : YM2=Y Screen(Y Mouse)
         Box HOLDXM,HOLDYM To XM2,YM2
         Box HOLDXM,HOLDYM To XM2,YM2
         Draw XM2,0 To XM2,SCRNHEIGHT-1
         Draw 0,YM2 To SCRNWIDTH-1,YM2
         Draw XM2,0 To XM2,SCRNHEIGHT-1
         Draw 0,YM2 To SCRNWIDTH-1,YM2
      Wend
      Gr Writing 1 : Box HOLDXM,HOLDYM To XM2,YM2
      If ARTMODE=5
         If HOLDXM>XM2
            Swap HOLDXM,XM2
         End If
         If HOLDYM>YM2
            Swap HOLDYM,YM2
         End If
         If HOLDXM<>XM2 and HOLDYM<>YM2
            Bar HOLDXM,HOLDYM To XM2,YM2
         End If
      End If
      If HOLDXM<>XM2 and HOLDYM<>YM2
         Print #2,HOLDXM : Print #2,HOLDYM : Print #2,XM2 : Print #2,YM2
      End If
   End If

   If ARTMODE=6 : Rem : paint
      Screen 0 : Paint XM,YM
      Print #2,XM : Print #2,YM
   End If

   If ARTMODE=7 : Rem : Text
      Screen 0
      While Mouse Key=1
         XM2=X Screen(X Mouse) : YM2=Y Screen(Y Mouse)
         Gr Writing 2 : Text XM2,YM2,WORD$
         Text XM2,YM2,WORD$
      Wend
      Gr Writing 0 : Text XM2,YM2,WORD$ : Gr Writing 1
      Print #2,XM2 : Print #2,YM2
   End If

   If ARTMODE=8 : Rem : circle
      NEWFLAG=0 : HOLDXM=XM : HOLDYM=YM
      Screen 0
      While Mouse Key=1
         XM2=X Screen(X Mouse) : YM2=Y Screen(Y Mouse)
         XM2=Abs(HOLDXM-XM2)+1 : YM2=Abs(HOLDYM-YM2)+1
         Gr Writing 3 : Ellipse HOLDXM,HOLDYM,XM2,YM2
         Ellipse HOLDXM,HOLDYM,XM2,YM2
      Wend
      Gr Writing 1 : Ellipse HOLDXM,HOLDYM,XM2,YM2
      Print #2,HOLDXM : Print #2,HOLDYM : Print #2,XM2 : Print #2,YM2
   End If
Pop Proc

POLYEND:
   If ARTMODE=1 Then Gosub PGON : Return
   If ARTMODE=2 Then Gosub PLINE
   Return
PGON:
   ARTMODE=1 : Gosub CLEARGRID : Box 0,0 To 39,12 : Ink CURRCOLOR
   Change Mouse 4 : MMODE=4
   NEWFLAG=1 : Screen 0 : Get Block 1,5,9,16,9 : Return
PLINE:
   ARTMODE=2 : Gosub CLEARGRID : Box 39,0 To 79,12 : Ink CURRCOLOR
   Change Mouse 4 : MMODE=4
   NEWFLAG=1 : Return
SEGPAINT:
   If XM<100
SEG:
      ARTMODE=3 : Gosub CLEARGRID : Box 79,0 To 99,12 : Ink CURRCOLOR
      Change Mouse 4 : MMODE=4
      NEWFLAG=1 : Return
   End If
PNT:
   ARTMODE=6 : Gosub CLEARGRID : Box 99,0 To 119,12 : Ink CURRCOLOR
   Change Mouse 6 : MMODE=6 : Return
BBOXBAR:
   If XM<140
RECBOX:
      ARTMODE=4 : Gosub CLEARGRID : Box 119,0 To 139,12 : Ink CURRCOLOR
      Change Mouse 4 : MMODE=4 : Return
   End If
RECBAR:
   ARTMODE=5 : Gosub CLEARGRID : Box 139,0 To 158,12 : Ink CURRCOLOR
   Change Mouse 4 : MMODE=4 : Return
OUTLYN:
   If OUTFLAG=0
      Change Mouse 4
      Screen 0 : Set Paint 1
      Screen 1 : Gosub CHECKWIDTH : Print #1,"Set Paint 1 : "; : Add LCOUNT,14
      If Ntsc
         Limit Mouse 271,215 To 431,239
      Else
         Limit Mouse 271,265 To 431,289
      End If
      While Mouse Click=0 : Wend
      XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
      If Ntsc
         Limit Mouse 112,215 To 431,239
      Else
         Limit Mouse 112,265 To 431,289
      End If
      ICONCOLNUM=((XM-160)/10)
      If ICONCOLNUM>NUMCOLORS-1
         ICONCOLNUM=NUMCOLORS-1
      End If
      ICONROWNUM=(YM)/13
      If NUMCOLORS<32
         ICONROWNUM=0
      End If
      OLCOLOR=ICONCOLNUM+(ICONROWNUM*16) : Screen 0 : Ink ,,OLCOLOR
      Gosub CHECKWIDTH : Print #1,"Ink ,,";OLCOLOR;" : "; : Add LCOUNT,11
      Screen 1 : Ink 17 : Polyline 30,17 To 32,22 To 36,14 : OUTFLAG=1
   Else
      Gosub CHECKWIDTH
      Screen 0 : Set Paint 0 : Print #1,"Set Paint 0 : "; : Add LCOUNT,14
      Screen 1 : Ink 0 : Bar 30,14 To 36,22 : OUTFLAG=0
   End If
   If ARTMODE>0 and CURRCOLOR>-1
      Limit Mouse XOFFSET,YOFFSET To XLIMIT,YLIMIT
   End If
   Change Mouse MMODE
   Screen 0 : Ink CURRCOLOR
   Return

PATTERN:
   OLDPCOLOR=PCOLOR : OLDPATNUM=PATNUM : Change Mouse 4
   Wind Open 1,0,0,20,4 : Set Pattern 0
   Ink 0,PCOLOR : Bar 0,0 To 158,24
   Ink 2 : Box 107,0 To 158,24 : Draw 107,13 To 158,13
   Ink 4,0 : Text 109,21,"Cancel" : Text 124,9,"OK" : Ink CURRCOLOR,PCOLOR
   Set Slider 0,1,7,2,0,0,4,0
   Set Pattern PATNUM : Bar 4,2 To 106,15
   Hslider 4,16 To 106,23,102,PATNUM*3,4 : Set Zone 3,4,16 To 106,23
   Set Zone 4,107,2 To 158,13 : Set Zone 5,107,14 To 158,24
   Set Zone 6,159,0 To 319,24
   Wait 5 : Rem so it doesn't re-set PATNUM value

   Repeat
      If Mouse Zone=3 and Mouse Key=1
         Limit Mouse X Hard(4),Y Hard(16) To X Hard(105),Y Hard(23)
         While Mouse Key=1
            X=X Screen(X Mouse)-4
            Set Slider 0,1,7,2,0,0,4,0
            Hslider 4,16 To 106,23,102,X,4 :
            PATNUM=((X+4)/3)-1
            Set Pattern PATNUM : Bar 4,2 To 106,15
            PATNUM$=Str$(PATNUM)-" " : Text 46,12,PATNUM$
         Wend
         Screen 0 : Set Pattern PATNUM : Screen 1
      End If

      If Mouse Zone=6 and Mouse Key=1
         XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
         Ink 0 : Box BX,BY To BX+10,BY+12
         ICONCOLNUM=((XM-160)/10)
         ICONROWNUM=(YM)/13
         PCOLOR=ICONCOLNUM+(ICONROWNUM*16)
         BX=(ICONCOLNUM*10)+159 : BY=(ICONROWNUM*12)
         Ink 17 : Box BX,BY To BX+10,BY+12
         Screen 0 : Ink CURRCOLOR,PCOLOR : Screen 1 : Ink CURRCOLOR,PCOLOR
            Set Pattern PATNUM : Bar 4,2 To 106,15
            PATNUM$=Str$(PATNUM)-" " : Text 46,12,PATNUM$
      End If
      If Ntsc
         Limit Mouse 112,215 To 431,239 : Rem : Screen 1 only...
      Else
         Limit Mouse 112,265 To 431,289
      End If
   Until Mouse Key=1 and Mouse Zone>3 and Mouse Zone<6

   If Mouse Zone=4 and Mouse Key=1
      If PATNUM<>OLDPATNUM
         Gosub CHECKWIDTH : Print #1,"Set Pattern ";PATNUM;" : ";
         Add LCOUNT,17 : Gosub CHECKWIDTH
      End If
      If PCOLOR<>OLDPCOLOR
         Print #1,"Ink ,";PCOLOR;" : "; : Add LCOUNT,10 : Gosub CHECKWIDTH
      End If
   End If
   If Mouse Zone=5 and Mouse Key=1
      PCOLOR=OLDPCOLOR : PATNUM=OLDPATNUM : Set Pattern PATNUM
   End If
   Wind Close
   Screen 0 : Set Pattern PATNUM : Ink CURRCOLOR,PCOLOR
   Screen 1 : Set Pattern 0
   If PATNUM=0
      Ink 0,1 : Bar 70,14 To 76,22
   Else
      Ink 17 : Polyline 70,17 To 72,22 To 76,14
   End If
   Ink CURRCOLOR
   If ARTMODE>0
      Limit Mouse XOFFSET,YOFFSET To XLIMIT,YLIMIT
   End If
   Change Mouse MMODE
Return

TXTPAL:
   If XM>99
TXT:
      Change Mouse 4 : MMODE=4
      If ARTMODE<>7
         Gosub CHECKWIDTH
         If GRMODE<>0
            Print #1,"Gr Writing 0 : "; : GRMODE=0 :
            Add LCOUNT,15 : Gosub CHECKWIDTH
         End If
      End If
      If HIDFLAG=1
         Screen Show 1
      End If
      Wind Open 1,0,0,39,3,1 : Border 3,5,1 : Print
      Line Input "Text? ";WORD$; : Wind Close
      If HIDFLAG=1
         Screen Hide 1
      End If
      If WORD$=""
         Return
      End If
      ARTMODE=7 : Gosub CLEARGRID : Box 99,12 To 119,24 : Ink CURRCOLOR
      Return
   End If

'else it's the palette requester... stay here 'til they hit OK or Cancel...
PAL:
   Change Mouse 4
   If HIDFLAG=1
      Screen Show 1
   End If
   Wind Open 1,0,0,20,4
   Ink 0 : Bar 0,0 To 158,24
   Ink 2 : Box 107,0 To 158,24 : Draw 107,13 To 158,13
   Ink 4,0 : Text 109,21,"Cancel" : Text 124,9,"OK"
   OLDCURRCOLOR=CURRCOLOR
NEWCOLOR:
   Proc RGBER
   Ink 4,0 : Text 1,7,CHEXR$ : Text 1,15,CHEXG$ : Text 1,23,CHEXB$

   Set Slider 0,1,7,2,0,0,4,0
   Hslider 10,2 To 106,8,96,CURRRED*6,6 : Set Zone 1,10,2 To 106,8
   Hslider 10,9 To 106,15,96,CURRGREEN*6,6 : Set Zone 2,10,9 To 106,15
   Hslider 10,16 To 106,23,96,CURRBLUE*6,6 : Set Zone 3,10,16 To 106,23
   Set Zone 4,107,2 To 158,13 : Set Zone 5,107,14 To 158,24
   Set Zone 6,159,0 To 319,24
   Wait 5 : Rem so it doesn't re-set currblue value

   Repeat
      If Mouse Zone=1 and Mouse Key=1
         Limit Mouse X Hard(10),Y Hard(2) To X Hard(105),Y Hard(8)
         While Mouse Key=1
            X=X Screen(X Mouse)-10
            Set Slider 0,1,7,2,0,0,4,0
            Hslider 10,2 To 106,8,96,X,6 :
            CURRRED=((X+6)/6)-1
            CHEXR$=Hex$(CURRRED) : CHEXR$=Right$(CHEXR$,1) : Text 1,7,CHEXR$
            CHEX$="$"+CHEXR$+CHEXG$+CHEXB$ :
            Screen 0 : Colour CURRCOLOR,Val(CHEX$)
            Screen 1 : Colour CURRCOLOR,Val(CHEX$)
         Wend
      End If
      If Mouse Zone=2 and Mouse Key=1
         Limit Mouse X Hard(10),Y Hard(9) To X Hard(105),Y Hard(15)
         While Mouse Key=1
            X=X Screen(X Mouse)-10
            Set Slider 0,1,7,2,0,0,4,0
            Hslider 10,9 To 106,15,96,X,6 :
            CURRGREEN=((X+6)/6)-1
            CHEXG$=Hex$(CURRGREEN) : CHEXG$=Right$(CHEXG$,1) : Text 1,15,CHEXG$
            CHEX$="$"+CHEXR$+CHEXG$+CHEXB$ : Colour CURRCOLOR,Val(CHEX$)
            Screen 0 : Colour CURRCOLOR,Val(CHEX$)
            Screen 1 : Colour CURRCOLOR,Val(CHEX$)
         Wend
      End If
      If Mouse Zone=3 and Mouse Key=1
         Limit Mouse X Hard(10),Y Hard(16) To X Hard(105),Y Hard(23)
         While Mouse Key=1
            X=X Screen(X Mouse)-10
            Set Slider 0,1,7,2,0,0,4,0
            Hslider 10,16 To 106,23,96,X,6 :
            CURRBLUE=((X+6)/6)-1
            CHEXB$=Hex$(CURRBLUE) : CHEXB$=Right$(CHEXB$,1) : Text 1,23,CHEXB$
            CHEX$="$"+CHEXR$+CHEXG$+CHEXB$ : Colour CURRCOLOR,Val(CHEX$)
            Screen 0 : Colour CURRCOLOR,Val(CHEX$)
            Screen 1 : Colour CURRCOLOR,Val(CHEX$)
         Wend
      End If
      If Mouse Zone=6 and Mouse Key=1
         XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
         Ink 0 : Box BX,BY To BX+10,BY+12
         ICONCOLNUM=((XM-160)/10)
         ICONROWNUM=(YM)/13
         CURRCOLOR=ICONCOLNUM+(ICONROWNUM*16)
         BX=(ICONCOLNUM*10)+159 : BY=(ICONROWNUM*12)
         Ink 17 : Box BX,BY To BX+10,BY+12
         Goto NEWCOLOR
      End If
      If Ntsc
         Limit Mouse 112,215 To 431,239 : Rem : Screen 1 only...
      Else
         Limit Mouse 112,265 To 431,289
      End If
   Until Mouse Key=1 and Mouse Zone>3 and Mouse Zone<6
   Change Mouse MMODE
   If Mouse Zone=4 and Mouse Key=1
      If LCOUNT>50
         Print #1,""
      End If
      Print #1,"Palette ";Hex$(Colour(0));
      For J=1 To NUMCOLORS-1
         Print #1,",";Hex$(Colour(J));
      Next J : Print #1,"" : LCOUNT=0
      For J=0 To 31
         OLDPAL$(J)=Hex$(Colour(J))
      Next J
   End If
   If Mouse Zone=5 and Mouse Key=1
      For J=0 To 31
         Screen 0 : Colour J,Val(OLDPAL$(J))
         Screen 1 : Colour J,Val(OLDPAL$(J))
      Next J
   End If
   Wind Close
   If HIDFLAG=1
      Screen Hide 1
   End If
   If ARTMODE>0
      Limit Mouse XOFFSET,YOFFSET To XLIMIT,YLIMIT
   End If
   CURRCOLOR=OLDCURRCOLOR
   Gosub CLEARCOLORGRID
   If CURRCOLOR<16
      ICONROWNUM=0 : ICONCOLNUM=CURRCOLOR
   Else
      ICONROWNUM=1 : ICONCOLNUM=CURRCOLOR-16
   End If
   BX=(ICONCOLNUM*10)+159 : BY=(ICONROWNUM*12)
   Ink 17 : Box BX,BY To BX+10,BY+12
   Return

CIRCQUIT:
   If XM<140
      Change Mouse 4 : MMODE=4
      ARTMODE=8 : Gosub CLEARGRID : Box 119,12 To 139,24 : Ink CURRCOLOR
      Return
   End If
QUIT:
   If GRMODE=0 Then Print #1,"Gr Writing 1 : "
   Print #1,""
   Limit Mouse : Close 1 : Close 2 : Kill "ram:XYclip.asc"
   Change Mouse 1 : Edit

COMMA:
   Change Mouse 5
   While Mouse Click=0 : Wend : Screen 0
   XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
   CURRCOLOR=Point(XM,YM) : Screen 1 : Gosub CLEARCOLORGRID
   If CURRCOLOR<16
      ICONROWNUM=0 : ICONCOLNUM=CURRCOLOR
   Else
      ICONROWNUM=1 : ICONCOLNUM=CURRCOLOR-16
   End If
   BX=(ICONCOLNUM*10)+159 : BY=(ICONROWNUM*12)
   Box BX,BY To BX+10,BY+12 : Screen 0 : Ink CURRCOLOR
   CFLAG=1 : Change Mouse MMODE : Return
CLEARGRID:
   Ink 2 : Box 0,0 To 39,24 : Box 79,0 To 119,24 : Box 139,0 To 158,24
   For Y=0 To 24 Step 12 : Draw 0,Y To 158,Y : Next Y : Draw 99,0 To 99,24
   Ink 17 : Return
CLEARCOLORGRID:
   Ink 0 : Box 159,0 To 319,24 : Draw 159,12 To 319,12
   For Y=169 To 309 Step 10 : Draw Y,0 To Y,24 : Next Y
   Ink 17 : Return
LLENNY:
   LLENX=3 : LLENY=3
   If X<100
      LLENX=2
      If X<10
         LLENX=1
      End If
   End If
   If Y<100
      LLENY=2
      If Y<10
         LLENY=1
      End If
   End If
   LLEN=LLENX+LLENY : Add LCOUNT,LLEN
   Return

E1: X01=X : Y01=Y : Return
E2: X02=X : Y02=Y : Return
E3: X03=X : Y03=Y : Return
E4: X04=X : Y04=Y : Return
E5: X05=X : Y05=Y : Return
E6: X06=X : Y06=Y : Return
E7: X07=X : Y07=Y : Return
E8: X08=X : Y08=Y : Return
E9: X09=X : Y09=Y : Return
E10: X10=X : Y10=Y : Return
E11: X11=X : Y11=Y : Return
E12: X12=X : Y12=Y : Return
E13: X13=X : Y13=Y : Return
E14: X14=X : Y14=Y : Return
E15: X15=X : Y15=Y : Return

P1: Polygon X01,Y01 To X01,Y01 : Return
P2: Polygon X01,Y01 To X02,Y02 : Return
P3: Polygon X01,Y01 To X02,Y02 To X03,Y03 : Return
P4: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 : Return
P5: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 : Return
P6: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 : Return
P7: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 : Return
P8: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 : Return
P9: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 : Return
P10: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 To X10,Y10 : Return
P11: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 To X10,Y10 To X11,Y11 : Return
P12: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 To X10,Y10 To X11,Y11 To X12,Y12 : Return
P13: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 To X10,Y10 To X11,Y11 To X12,Y12 To X13,Y13 : Return
P14: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 To X10,Y10 To X11,Y11 To X12,Y12 To X13,Y13 To X14,Y14 : Return
P15: Polygon X01,Y01 To X02,Y02 To X03,Y03 To X04,Y04 To X05,Y05 To X06,Y06 To X07,Y07 To X08,Y08 To X09,Y09 To X10,Y10 To X11,Y11 To X12,Y12 To X13,Y13 To X14,Y14 To X15,Y15 : Return
Return
ARTMODE1:
   Gosub PLUSINK : Close 2 : Open In 2,"ram:XYclip.asc"
   Screen 0 : Put Block 1 : Screen 1
   Gosub CHECKWIDTH
   If GRMODE<>1
      Print #1,"Gr Writing 1 : "; : GRMODE=1 : Add LCOUNT,15 : Gosub CHECKWIDTH
   End If
   If LCOUNT>50 Then Print #1,"" : LCOUNT=0
   Print #1,"Polygon "; : Add LCOUNT,8
   Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
   Print #1,X;",";Y; : Gosub LLENNY : NUMELEMENTS=1 : Gosub E1
   While Not Eof(2)
      Input #2,X$ : Input #2,Y$ : X=Val(X$) : Y=Val(Y$)
      X$=X$-" " : Y$=Y$-" "
      Print #1," To ";X$;",";Y$; : Add LCOUNT,5 : Gosub LLENNY
      Inc NUMELEMENTS
      On NUMELEMENTS Gosub E1,E2,E3,E4,E5,E6,E7,E8,E9,E10,E11,E12,E13,E14,E15
   Wend
   Screen 0 : On NUMELEMENTS Gosub P1,P2,P3,P4,P5,P6,P7,P8,P9,P10,P11,P12,P13,P14,P15
   Screen 1 : NEWFLAG=1 : Print #1," : "; : Add LCOUNT,3
   Close 2 : Open Out 2,"ram:XYclip.asc"
   Return
PLUSINK:
   If CFLAG=0 or CURRCOLOR=HOLDCOLOR Then Return
   Gosub CHECKWIDTH : Print #1,"Ink ";CURRCOLOR;" : "; : Add LCOUNT,10
   Gosub CHECKWIDTH : CFLAG=0 : HOLDCOLOR=CURRCOLOR : Return
CHECKWIDTH:
   If LCOUNT>CODEWIDTH Then Print #1,"" : LCOUNT=0
   Return
End Proc

Procedure SCRNCHECK
   Shared GOTTASETUP,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,SCRNTYPE$
   Shared XOFFSET,YOFFSET,XLIMIT,YLIMIT
   Dir$="Ram:" : FILE$="Ram:ArtCoderSettings"
   If Exist(FILE$)
      If Key Shift>0
         GOTTASETUP=-1 : Pop Proc
      Else
         Open In 1,FILE$
         Input #1,SCRNWIDTH$,SCRNHEIGHT$,NUMCOLORS$,SCRNTYPE$,XOFFSET$,YOFFSET$,XLIMIT$,YLIMIT$
         Close 1
         SCRNWIDTH=Val(SCRNWIDTH$) : SCRNHEIGHT=Val(SCRNHEIGHT$)
         NUMCOLORS=Val(NUMCOLORS$) : XOFFSET=Val(XOFFSET$) : YOFFSET=Val(YOFFSET$)
         XLIMIT=Val(XLIMIT$) : YLIMIT=Val(YLIMIT$)
         If SCRNTYPE$="Lowres"
            Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Lowres
         End If
         If SCRNTYPE$="Hires"
            Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Hires
         End If
         If SCRNTYPE$="Lowres+Laced"
            Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Lowres+Laced
         End If
         If SCRNTYPE$="Hires+Laced"
            Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Hires+Laced
         End If
         Curs Off : Flash Off
         Screen Display 0,XOFFSET,YOFFSET,SCRNWIDTH,SCRNHEIGHT
         Ink ,0
         If NUMCOLORS=2
            Cls 1
         End If
      End If
   Else
      GOTTASETUP=-1
   End If
   End Proc

Procedure SCRNSETUP
   Shared SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,SCRNTYPE$
   Shared XOFFSET,YOFFSET,XLIMIT,YLIMIT
   Screen Open 0,320,200,16,Lowres
   Wait Vbl
   Limit Mouse : Ink 2
   If Ntsc
      Text 172,9,"320x200   352x240" : Text 172,21,"640x200   704x240"
      Text 172,33,"320x400   352x480" : Text 172,45,"640x400   704x480"
   Else
      Text 172,9,"320x256   352x290" : Text 172,21,"640x256   704x290"
      Text 172,33,"320x512   352x566" : Text 172,45,"640x512   704x566"
   End If
   Text 54,9,"Screen Size?" : Text 172,75,"2   4   8  16  32"
   Draw 191,66 To 191,78 : Draw 223,66 To 223,78 : Draw 253,66 To 253,78
   Draw 284,66 To 284,78 : Text 15,75,"Number of Colors?"
   Box 159,36 To 319,48 : Draw 241,0 To 241,48 : Box 159,0 To 319,12
   Box 159,12 To 319,24 : Box 159,24 To 319,36 : Box 159,66 To 319,78

   Repeat
      If Mouse Click=1 Then Gosub CLICKHANDLER
   Until SCRNWIDTH>0 and NUMCOLORS>0

   If NUMCOLORS=2
      Cls 1
   End If
   Pop Proc

CLICKHANDLER:
   XM=X Screen(X Mouse) : YM=Y Screen(Y Mouse)
   If XM<159 Then Return
   If YM>78 Then Return
   If YM>48 and YM<66 Then Return
   If YM<49
      If XM<242
         If YM<12
            If Ntsc
               SCRNWIDTH=320 : SCRNHEIGHT=200
            Else
               SCRNWIDTH=320 : SCRNHEIGHT=256
            End If
            SCRNTYPE$="Lowres"
            Gosub CLEARGRID : Box 159,0 To 241,12 : Return
         End If
         If YM<24
            If Ntsc
               SCRNWIDTH=640 : SCRNHEIGHT=200
            Else
               SCRNWIDTH=640 : SCRNHEIGHT=256
            End If
            SCRNTYPE$="Hires"
            Gosub CLEARGRID : Box 159,12 To 241,24 :
            If NUMCOLORS=32
               NUMCOLORS=16 : Gosub CLEARCOLORGRID : Box 253,66 To 284,78
            End If
            Return
         End If
         If YM<34
            If Ntsc
               SCRNWIDTH=320 : SCRNHEIGHT=400
            Else
               SCRNWIDTH=320 : SCRNHEIGHT=512
            End If
            SCRNTYPE$="Lowres+Laced"
            Gosub CLEARGRID : Box 159,24 To 241,36 : Return
         End If
            If Ntsc
               SCRNWIDTH=640 : SCRNHEIGHT=400
            Else
               SCRNWIDTH=640 : SCRNHEIGHT=512
            End If
            SCRNTYPE$="Hires+Laced"
            Gosub CLEARGRID : Box 159,36 To 241,48
            If NUMCOLORS=32
               NUMCOLORS=16 : Gosub CLEARCOLORGRID : Box 253,66 To 284,78
            End If
            Return
      Else
         If YM<12
            If Ntsc
               SCRNWIDTH=352 : SCRNHEIGHT=240
            Else
               SCRNWIDTH=352 : SCRNHEIGHT=290
            End If
            SCRNTYPE$="Lowres"
            Gosub CLEARGRID : Box 241,0 To 319,12 : Return
         End If
         If YM<24
            If Ntsc
               SCRNWIDTH=704 : SCRNHEIGHT=240
            Else
               SCRNWIDTH=704 : SCRNHEIGHT=290
            End If
            SCRNTYPE$="Hires"
            Gosub CLEARGRID : Box 241,12 To 319,24
            If NUMCOLORS=32
               NUMCOLORS=16 : Gosub CLEARCOLORGRID : Box 253,66 To 284,78
            End If
            Return
         End If
         If YM<34
            If Ntsc
               SCRNWIDTH=352 : SCRNHEIGHT=480
            Else
               SCRNWIDTH=352 : SCRNHEIGHT=566
            End If
            SCRNTYPE$="Lowres+Laced"
            Gosub CLEARGRID : Box 241,24 To 319,36 : Return
         End If
            If Ntsc
               SCRNWIDTH=704 : SCRNHEIGHT=480
            Else
               SCRNWIDTH=704 : SCRNHEIGHT=566
            End If
            SCRNTYPE$="Hires+Laced"
            Gosub CLEARGRID : Box 241,36 To 319,48
            If NUMCOLORS=32
               NUMCOLORS=16 : Gosub CLEARCOLORGRID : Box 253,66 To 284,78
            End If
            Return
      End If
   End If
   If YM>65
      If XM<191
         NUMCOLORS=2 : Gosub CLEARCOLORGRID : Box 159,66 To 191,78 : Return
      End If
      If XM<223
         NUMCOLORS=4 : Gosub CLEARCOLORGRID : Box 191,66 To 223,78 : Return
      End If
      If XM<253
         NUMCOLORS=8 : Gosub CLEARCOLORGRID : Box 223,66 To 253,78 : Return
      End If
      If XM<284
         NUMCOLORS=16 : Gosub CLEARCOLORGRID : Box 253,66 To 284,78 : Return
      End If
         If SCRNWIDTH>400
            NUMCOLORS=16 : Gosub CLEARCOLORGRID : Box 253,66 To 284,78 : Return
         Else
            NUMCOLORS=32 : Gosub CLEARCOLORGRID : Box 284,66 To 319,78 : Return
         End If
   End If
   Return
CLEARGRID:
   Ink 2 : Box 159,0 To 319,12 : Box 159,12 To 319,24 : Box 159,24 To 319,36
   Box 159,36 To 319,48 : Draw 241,0 To 241,48 : Ink 4
   Return
CLEARCOLORGRID:
   Ink 2 : Box 159,66 To 319,78 : Draw 191,66 To 191,78 : Draw 223,66 To 223,78
   Draw 253,66 To 253,78 : Draw 284,66 To 284,78 : Ink 4
   Return
End Proc

Procedure SCRNCENTER
   Shared SCRNWIDTH,SCRNHEIGHT,SCRNTYPE$,NUMCOLORS,XOFFSET,YOFFSET,XLIMIT,YLIMIT
   If SCRNTYPE$="Lowres"
      Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Lowres
   End If
   If SCRNTYPE$="Hires"
      Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Hires
   End If
   If SCRNTYPE$="Lowres+Laced"
      Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Lowres+Laced
   End If
   If SCRNTYPE$="Hires+Laced"
      Screen Open 0,SCRNWIDTH,SCRNHEIGHT,NUMCOLORS,Hires+Laced
   End If

   Cls 1 : Curs Off : Flash Off : Box 0,0 To SCRNWIDTH-1,SCRNHEIGHT-1
   Box 0,2 To SCRNWIDTH-1,SCRNHEIGHT-3 : Box 0,4 To SCRNWIDTH-1,SCRNHEIGHT-5
   Locate ,10 : Centre "Center screen then click mouse."
   X Mouse=190 : Y Mouse=30 : Wait 10
   While Mouse Click<>1 :
      XOFFSET=X Mouse-88 : YOFFSET=Y Mouse-38
      Gosub CUTXOFFSET
      Screen Display 0,XOFFSET,YOFFSET,SCRNWIDTH,SCRNHEIGHT
   Wend
   XLIMIT=X Hard(SCRNWIDTH-1) : YLIMIT=Y Hard(SCRNHEIGHT-1)
   Open Out 1,"Ram:ArtCoderSettings"
      Print #1,SCRNWIDTH : Print #1,SCRNHEIGHT : Print #1,NUMCOLORS
      Print #1,SCRNTYPE$ : Print #1,XOFFSET : Print #1,YOFFSET
      Print #1,XLIMIT : Print #1,YLIMIT
   Close 1 : Cls 1 : Pop Proc

CUTXOFFSET:
   If XOFFSET<96 Then XOFFSET=80 : Return
   If XOFFSET<112 Then XOFFSET=96 : Return
   If XOFFSET<128 Then XOFFSET=112 : Return
   If XOFFSET<144 Then XOFFSET=128
   Return
End Proc

Procedure CHECKPATTERN
   Shared PATNUM,CURRCOLOR,PCOLOR,OUTFLAG
   Screen 0 : Get Block 1,0,0,32,18
   Draw 0,0 To 1,1 : CURRCOLOR=Point(1,1) : Bar 0,0 To 17,17
   OLCOLOR=Point(0,0)
   PIX$=""
   Restore CHECKPOINTS
   For J=1 To 12
      Read X,Y : PIXCHECK=Point(X,Y)
      If PIXCHECK<>CURRCOLOR Then PCOLOR=PIXCHECK
   Next J
   Ink 0,1,2 : Bar 0,0 To 17,17 :
   TESTOLCOLOR=Point(0,0) : If TESTOLCOLOR=2 Then OUTFLAG=1
   Restore CHECKPOINTS
   For J=1 To 12
      Read X,Y : PIXCHECK=Point(X,Y) : PIX$=PIX$+Str$(PIXCHECK)-" "
   Next J
   Restore PATTERNS
   Gosub CHECKPAT
   Ink CURRCOLOR,PCOLOR,OLCOLOR : Screen 1 : Ink 17
   If OUTFLAG=1 Then Polyline 30,17 To 32,22 To 36,14
   If PATNUM>0 Then Polyline 70,17 To 72,22 To 76,14
   Screen 0 : Put Block 1
   Pop Proc

CHECKPAT: Rem: finds value of PATNUM...
   PATNUM=-1
   While PATTERN$<>PIX$
      Inc PATNUM : Read PATTERN$
   Wend
   Return

PATTERNS:
Data "000000000000","111111111111","101010101110","110111111101","101111101111"
Data "110111110001","100111100001","011111111111","010000000000","011011111101"
Data "111111101110","100111000001","100001111100","000111111101","101111000010"
Data "000000111100","000000011100","010111111101","111101100011","111111001111"
Data "111111110011","111111000011","010111111111","000011111111","010111111110"
Data "111111101111","111111110111","111111000011","101110111111","101010111111"
Data "101010111110","101010101110","101000101110","100000001100","100000000000"

CHECKPOINTS:
Data 5,2,3,3,4,3,5,3,6,3,7,3,8,3,16,2,1,8,1,16,4,11,4,12
End Proc

Procedure RGBER
   Shared CURRCOLOR,CURRRED,CURRGREEN,CURRBLUE,CHEXR$,CHEXG$,CHEXB$,GRMODE
   CHEX$=Hex$(Colour(CURRCOLOR),3)
   CHEXR$=Mid$(CHEX$,2,1) : CHEXG$=Mid$(CHEX$,3,1) : CHEXB$=Right$(CHEX$,1)
   CURRCHEX$=CHEXR$ : Gosub CHECKER : CURRRED=CHEX
   CURRCHEX$=CHEXG$ : Gosub CHECKER : CURRGREEN=CHEX
   CURRCHEX$=CHEXB$ : Gosub CHECKER : CURRBLUE=CHEX
   Pop Proc
CHECKER:
   If CURRCHEX$="A" Then CHEX=10 : Return
   If CURRCHEX$="B" Then CHEX=11 : Return
   If CURRCHEX$="C" Then CHEX=12 : Return
   If CURRCHEX$="D" Then CHEX=13 : Return
   If CURRCHEX$="E" Then CHEX=14 : Return
   If CURRCHEX$="F" Then CHEX=15 : Return
   CHEX=Val(CURRCHEX$) : Return
End Proc